Steigende / sinkende Monatsplanwerte in Excel ermitteln

In einem früheren Beitrag war die Ermittlung von Monatsplanwerten mittels Saisonfaktoren das Thema.

Dieser Beitrag behandelt die Ermittlung steigender oder sinkender Monatsplanwerte aus einem Jahresplanwert heraus.

Steigende Werte können z.B. bei einem Startup-Unternehmen ein Thema sein. Erst einmal klein beginnen und langsam steigern.

Sinkende Werte wiederum können ihre Notwendigkeit mit auslaufenden Geschäften begründen.

Der Beitrag erläutert neben gleichen linearen Werten jeweils zwei Varianten mit steigenden und zwei Varianten mit sinkenden Planwerten.

1. Linear gleiche Planwerte

Die folgende Tabelle zeigt die ersten sechs Monate mit den berechneten Planwerten.

KAPZ1

In B4 steht der Jahresplanwert, der in linear gleiche zwölf Werte aufgeteilt werden soll. Der Faktor aus B5 spielt hierbei noch keine Rolle.

Schreibe in B8 diese Formel

=$B$4/12

und ziehe sie bis M8 durch. Die Zelle N8 erhält die Formel

=SUMME(B8:M8)

und dient der Kontrolle, ob der Jahresplanwerte vollständig verteilt wurde. Ziehe sie bis N12 herunter.

Grafisch sieht der Werteverlauf über die 12 Perioden so aus:

KAPZ6

2. Exponentiell steigende Planwerte

In der Tabelle ist jetzt eine weitere Zeile hinzugefügt.

KAPZ2

Schreibe in B9 diese Formel

=-KAPZ($B$5-1;B7;12;0;$B$4;0)

und ziehe sie bis M9 durch. In N9 steht wieder die Summenformel.

Für die Berechnung exponentiell steigender Werte verwendest Du hier die finanzmathematische Funktion KAPZ, zweckentfremdet, denn sie ist ursprünglich nicht für diesen Zweck vorgesehen. Aber sie eignet sich, den beabsichtigten Zweck zu erreichen.

Die Syntax dieser Funktion lautet:

KAPZ(Zins;Zr;Zzr;Bw;[Zw];[F])

Als Argument Zins verwendest Du jetzt den Faktor in B5 abzüglich 1.

Das Argument Zr, die jeweilige Periode, entnimmst Du jeweils der Zeile 7.

Zzr zeigt hier, über wie viele Perioden geplant werden soll. Bei einem Jahr sind es 12 Perioden (Monate).

Als Barwert (Bw) gibst Du den Wert 0 ein, als Zw (Zielwert oder Endwert) den Bezug auf B4, den Jahresplanwert.

Mit dem Argument F entscheidest Du, ob die Zahlung jeweils am Ende der Periode (0) oder am Anfang der Periode (1) anfallen soll. Du entscheidest Dich hier für das Periodenende.

Vor die Formel setzt Du jetzt noch ein Minuszeichen, da KAPZ die Werte als Auszahlung betrachtet. Auszahlungen bekommen in der Finanzmathematik das negative Vorzeichen. Planwerte sollen aber positiv sein.

Erhöhst Du den Faktor in B5 nun z.B. auf 1,09, sinkt der Anfangswert in Periode 1 und steigt der Wert in Periode 12. Senkst Du den Faktor, steigt der Wert in Periode 1 und sinkt der Wert in Periode 12. Die Werte der anderen Perioden verhalten sich ähnlich.

Wichtig ist, dass die Summe in N9 in jedem Fall 232.000 beträgt.

Nun noch die Grafik:

KAPZ7

3. Linear steigende Planwerte

KAPZ3

Die Tabelle enthält nun eine weitere Zeile.

Schreibe in B10 diese Formel

=STEIGUNG($B9:$M9;$B7:$M7)*B7+ACHSENABSCHNITT($B9:$M9;$B7:$M7)

und ziehe sie bis M10 durch.

Die Formel bezieht sich auf die vorher mit KAPZ berechneten exponentiellen Werte. Bezogen auf die mit STEIGUNG und ACHSENABSCHNITT verwendete Regressionsgeraden werden die linearen Werte ermittelt:

Steigung * Periode + Achsenabschnitt

Die so ermittelten linear steigenden Planwerte verändern sich ebenfalls, wenn der Faktor verändert wird.

Und die Grafik:

KAPZ8

4. exponentiell sinkende Planwerte

KAPZ4

In Zeile 11 wird nun eine gegenläufige Variante vorgestellt.

Die Formel in B11 ist ähnlich der in B9.

=-KAPZ(1-$B$5;B7;12;0;$B$4;0)

Allerdings wird das Argument Zins jetzt durch Subtraktion des Faktors von 1 errechnet.

Alle weiteren Erläuterungen aus Abschnitt 2 treffen auch hier zu.

Hier noch die Grafik:

KAPZ9

5. Linear sinkende Planwerte

Füge der Tabelle nun eine weitere Zeile zu.

KAPZ5

Die Formel in B12 lautet:

=STEIGUNG($B11:$M11;$B7:$M7)*B7+ACHSENABSCHNITT($B11:$M11;$B7:$M7)

Sie ist damit im Grunde identisch mit der Formel in B10, nur dass sich STEGUNG und ACHSENABSCHNITT auf Zeile 11 beziehen.

Auch diese Werte verändern sich, wenn der Faktor in B5 verändert wird.

Abschließend noch die Grafik:

KAPZ10

6. Zusammenfassung

Bei Bedarf lassen sich monatliche Planwerte, die steigen oder sinken mit den vorgestellten Methoden berechnen.

Willst Du in B9 z.B. mit einem Wert von glatt 10.000 starten, lässt sich ein Weg mit der Zielwertsuche finden.

Rufe die Zielwertsuche über das Menü Daten / Prognose / Was-wäre-wenn-Analyse auf und nehme diese Einträge vor:

KAPZ11

Der Faktor in B5 ändert sich auf 1,11350348 und in B9 steht der gewünschte Wert 10.000.

Kommentar verfassen

Trage deine Daten unten ein oder klicke ein Icon um dich einzuloggen:

WordPress.com-Logo

Du kommentierst mit Deinem WordPress.com-Konto. Abmelden /  Ändern )

Twitter-Bild

Du kommentierst mit Deinem Twitter-Konto. Abmelden /  Ändern )

Facebook-Foto

Du kommentierst mit Deinem Facebook-Konto. Abmelden /  Ändern )

Verbinde mit %s